split into consumer flake and dev flake

.envrc

@@ -1 +1 @@
-use flake
+use flake ./dev

.github/workflows/check.yml

@@ -21,4 +21,4 @@ jobs:
     steps:
       - uses: actions/checkout@v5
       - uses: cachix/install-nix-action@v31
-      - run: nix flake check
+      - run: nix flake check ./dev

.vscode/settings.json

@@ -1,5 +1,5 @@
 {
   "[nix]": {
-    "editor.defaultFormatter": "brettm12345.nixfmt-vscode"
+    "editor.defaultFormatter": "VanCoding.vscode-treefmt-nix"
   }
 }

dev/checks.nix

@@ -0,0 +1,80 @@
+{
+  perSystem =
+    { pkgs, ... }:
+    let
+      prisma-factory = import ../prisma.nix;
+      yarn-v1 = pkgs.writeShellApplication {
+        name = "yarn-v1";
+        checkPhase = "";
+        runtimeInputs = [ pkgs.yarn ];
+        text = "yarn $@";
+      };
+      yarn-berry = pkgs.writeShellApplication {
+        name = "yarn-berry";
+        checkPhase = "";
+        runtimeInputs = [ pkgs.yarn-berry ];
+        text = "yarn $@";
+      };
+    in
+    {
+      checks =
+        (pkgs.callPackages ../tests.nix {
+          fetcherMode = "new";
+          inherit
+            pkgs
+            prisma-factory
+            yarn-v1
+            yarn-berry
+            ;
+        })
+        // (pkgs.callPackages ../tests.nix {
+          fetcherMode = "legacy";
+          inherit
+            pkgs
+            prisma-factory
+            yarn-v1
+            yarn-berry
+            ;
+        })
+        // {
+          fetcher-assert-npm =
+            let
+              # force download debian for consistent hash across systems
+              binaryTargetBySystem = {
+                x86_64-linux = "debian";
+                aarch64-linux = "debian";
+                x86_64-darwin = "debian";
+                aarch64-darwin = "debian";
+              };
+              prisma-legacy = prisma-factory {
+                inherit pkgs binaryTargetBySystem;
+                hash = "sha256-R9PG286KQTbzF0r/PPcShUkMiYam2prRh/JICjmhCZA=";
+              };
+              prisma-new =
+                lockName: lockFile:
+                prisma-factory {
+                  inherit pkgs binaryTargetBySystem;
+                  hash = "sha256-R9PG286KQTbzF0r/PPcShUkMiYam2prRh/JICjmhCZA=";
+                  ${lockName} = lockFile;
+                };
+            in
+            assert
+              (prisma-legacy.fromNpmLock ../npm/package-lock.json).env
+              == (prisma-new "npmLock" ../npm/package-lock.json).env;
+            pkgs.hello;
+          prisma-next =
+            (prisma-factory {
+              pkgs = pkgs;
+              versionString = "6.20.0-16.next-0c19ccc313cf9911a90d99d2ac2eb0280c76c513";
+              hash =
+                {
+                  x86_64-linux = "sha256-JWX+N/mmp9uJLcv4XFbQ3yg34fFf2BLIUpOLrrfTjEM=";
+                  x86_64-darwin = "sha256-WNwFOoeDOebbfAh4y/NvZCyE9otaJdg2hHb4ifEFD+Y=";
+                  aarch64-linux = "sha256-f9FuPZaGx0FwKo4pA9f8g82MTcAzYLwWslxjb7oqk6E=";
+                  aarch64-darwin = "sha256-NMI+JcP3epBO3V37D19TDgzivMnPekgrYqUrXB6qNV0=";
+                }
+                .${pkgs.system};
+            }).package;
+        };
+    };
+}

dev/flake.nix

@@ -0,0 +1,23 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    treefmt-nix.url = "github:numtide/treefmt-nix";
+    treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";
+  };
+  outputs =
+    inputs:
+    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = [
+        "x86_64-linux"
+        "aarch64-linux"
+        "x86_64-darwin"
+        "aarch64-darwin"
+      ];
+      imports = [
+        ./treefmt.nix
+        ./shell.nix
+        ./checks.nix
+      ];
+    };
+}

dev/shell.nix

@@ -0,0 +1,15 @@
+{
+  perSystem =
+    { pkgs, config, ... }:
+    {
+      devShells.default = pkgs.mkShell {
+        buildInputs = [
+          pkgs.nodejs_24
+          pkgs.pnpm
+          pkgs.bun
+          pkgs.stdenv.cc.cc.lib
+          config.treefmt.build.wrapper
+        ];
+      };
+    };
+}

dev/treefmt.nix

@@ -0,0 +1,7 @@
+{ inputs, ... }:
+{
+  imports = [ inputs.treefmt-nix.flakeModule ];
+  perSystem.treefmt = {
+    programs.nixfmt.enable = true;
+  };
+}