How to disable header name downcasing in request header

[josv]

Hi,

Using req 0.5.8, to my great satisfaction.

However I have one issue with a non-compliant server that insists on receiving the header "Cookie" (case sensitive). I can not change this server, so I wondered how I can make req generate the request with the header name not downcased?

I tried:

   req =
      Req.new(url: url, connect_options: [transport_opts: [verify: :verify_none]])

    #  |> Req.Request.put_header("Cookie", "mysession=#{session_id}")
    req = put_in(req.headers["Cookie"], List.wrap("mysession=#{session_id}"))
    Req.get(req)

But that didn't help.

[wojtekmach]

Thank you for the report. This is slightly tricky because Mint by default downcases header names and since its v1.6 it is possible to augment that with :case_sensitive_headers, however there's not at the moment an easy way to pass that option. I'll improve it however in the meantime you can start your own Finch pool like below and you should be good to go:

Mix.install([
  :req
])

{:ok, sock} = :gen_tcp.listen(8080, [:binary, active: false, reuseaddr: true])

Task.start_link(fn ->
  {:ok, sock} = :gen_tcp.accept(sock)
  {:ok, data} = :gen_tcp.recv(sock, 0, :infinity)
  IO.puts(data)

  :gen_tcp.send(sock, """
  HTTP/1.1 200 OK\r
  content-length: 2\r
  \r
  ok
  """)

  Process.sleep(:infinity)
end)

{:ok, _} =
  Finch.start_link(
    name: MyFinch,
    pools: %{
      default: [
        protocols: [:http1],
        conn_opts: [
          case_sensitive_headers: true
        ]
      ]
    }
  )

Req.new(
  url: "http://localhost:8080",
  finch: MyFinch
)
|> then(&put_in(&1.headers["Cookie"], ["sid=foo"]))
|> Req.request!()

[wojtekmach]

And yeah setting Req :headers and pit_header and similar will downcase the name in Req so manually adjusting req.headers is the way to go.

[josv]

Thank you, Wojtek. This indeed solves the issue.

As far as I am concerned, this issue can be closed. Do you want me to do it or should it stay open to track "an easy way to pass :case_sensitive_headers option"