dotfiles/flake.nix at main · velllu/dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";

    stylix = {
      url = "github:nix-community/stylix/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    home-manager = {
      url = "github:nix-community/home-manager/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    quickshell = {
      url = "git+https://git.outfoxxed.me/outfoxxed/quickshell";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, ... } @ inputs:
    let
      inherit (self) outputs;
      system = "x86_64-linux";

      # Template
      mkSystem = modules: nixpkgs.lib.nixosSystem {
        inherit system;
        specialArgs = { inherit inputs outputs; };
        modules = [
          inputs.stylix.nixosModules.stylix
          inputs.home-manager.nixosModules.home-manager
          {
            home-manager = {
              useGlobalPkgs = true;
              useUserPackages = true;
              extraSpecialArgs = { inherit inputs; };
            };
          }
        ] ++ modules; # Append host-specific modules
      };
    in
    {
      nixosConfigurations = {
        # Fully featured system
        # Runnable as the default
        nixos = mkSystem [
          ./nixos/configuration.nix
          ./nixos/extra.nix
        ];

        # Minimal system with heavy applications left out
        # Runnable with `sudo nixos-rebuild switch --flake .#minimal`
        minimal = mkSystem [
          ./nixos/configuration.nix
        ];
      };
    };
}