SofaPython3/package.nix at master · sofa-framework/SofaPython3 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
{
  cmake,
  lib,
  python3Packages,
  qt6Packages,
  sofa,
  stdenv,
}:

stdenv.mkDerivation {
  pname = "sofa-python3";
  version = "25.06";

  src = lib.fileset.toSource {
    root = ./.;
    fileset = lib.fileset.unions [
      ./bindings
      ./CMake
      ./CMakeLists.txt
      ./constants
      ./docs
      ./examples
      ./Plugin
      ./SofaPython3Config.cmake.in
      ./splib
      ./Testing
    ];
  };

  nativeBuildInputs = [
    cmake
    qt6Packages.libqglviewer
    qt6Packages.wrapQtAppsHook
  ];
  propagatedBuildInputs = [
    python3Packages.pybind11
    python3Packages.scipy
    sofa
  ];

  # help locate FindQGLViewer.cmake
  cmakeFlags = [
    "-DCMAKE_MODULE_PATH=${sofa.src}/cmake/Modules"
  ];

  meta = {
    description = "python plugin for Sofa offering a pythonic interface and python3 support";
    homepage = "https://github.com/sofa-framework/SofaPython3";
    license = lib.licenses.lgpl21Only;
    maintainers = with lib.maintainers; [ nim65s ];
    platforms = lib.platforms.unix ++ lib.platforms.windows;
  };
}