main.easel

pub game fn World.Main() {
    Gravity = 30

    Music(@stackMastersTheme.mp3, loop=true)
    ButtonRemap(Tap, Click)

    SolidBackground(#181818)
    Camera(@(0,0), radius=@(5, 9))
    CameraBoundary(bottom=9)
    Spawn boundary {
        Boundary(height=100, pos=@(0, 8 + height/2), heading=0, isFloor=true)
    }
    Spawn boundary {
        Boundary(height=100, pos=@(0, -50 - height/2), heading=0.5rev)
    }
    Spawn boundary {
        Boundary(height=100, pos=@(-5 - height/2, 0), heading=-0.25rev)
    }
    Spawn boundary {
        Boundary(height=100, pos=@(5 + height/2, 0), heading=0.25rev)
    }

    Ears(@(0, 10)) // Ears at bottom
    
    Toolbar {
        VolumeToggle
    }
    
    SpawnEachPlayer owner {
        HasPlayedBefore = true
        
        DiceDismantler(numDiceInRow=5) color {
            let h, s, l = color.HSL
            BoundaryColor = HSL(h, 0.33*s, 0.33*l)

            PlayerLevel += 1
        }

        await PlayTutorial

        loop {
            let elapsed = await PlayOneRound
            let isNewHighScore = SubmitHighScore(elapsed)
            await GameOverDialog(elapsed=, isNewHighScore=)
            
            // Clear board before next game
            for dice in Query(filter=Category:Dice) {
                dice.Expire
            }
        }
    }
}