bee.easel

use color=#fc0
const BeeAccelerationPerTick = 0.05
const SnapRadius = 1.5

pub field unit.BeeTrajectory
pub signal unit.BeeTrajectoryChanged

pub fn unit.Bee() {
    use body=unit
    use layer=Layer:Bee
    use radius=1, shape=Circle

    Body(pos=@(0.5 * HBoundaryRadius * SignedRandom, 0.5 * VBoundaryRadius * SignedRandom))
    PolygonCollider(category=Category:Bee)

    {
        use radius=2*radius
        ImageSprite(@bee-body.svg, color=#000, opacity=0.3, screenOffset=@(0, 2))
        ImageSprite(@bee-body.svg, color=, shading=0.5)
        ImageSprite(@bee-eyes.svg)
        ImageSprite(@bee-wings-*.svg, frameInterval=3, opacity=0.5)
    }

    DecaySpeed(0.03)

    BeeTrajectory = []
    with BeeTrajectoryChanged {
        await Paint
        
        use luminous=1, radius=0.1, color=#f60, layer=Layer:Beeline
        Strand(to=BeeTrajectory[0], glare=0.01, bloom=2, bloomAlpha=1, opacity=0.5, layer=layer-1)
        PolygonSprite(body=@(0,0), shape=Line(BeeTrajectory, cap=true), glare=0.01, bloom=2, bloomAlpha=1, layer=layer-1)
    }

    on BeforePhysics {
        let head = BeeTrajectory[0] ?? QueryNearest(filter=Category:Pollen).Pos
        if !head {
            await BeeTrajectoryChanged
            continue
        }

        let delta = head - (Pos + 2*Velocity/1s)

        Velocity += delta.Truncate(BeeAccelerationPerTick)
        
        if delta.Length <= 0.5 {
            BeeTrajectory.Shift
            BeeTrajectoryChanged
        }
    }

    on Paint {
        Heading = Velocity.Angle
    }
}

pub fn this.BeeSwarmControls([owner]) {
    on ButtonDown(Click) {
        // Find which trajectory to extend/replace
        let closest = Pointer.QueryNearest(filter=Category:Bee)
        if !(closest && closest.BeeTrajectory) { continue }

        let startNewTrajectory = true
        let closestDistance = Pointer.Distance(closest.Pos)
        for use unit in Query(filter=Category:Bee) {
            let tail = BeeTrajectory[BeeTrajectory.Length - 1]
            if !tail { continue }
            
            let distance = Pointer.Distance(tail)
            if distance < closestDistance {
                closest = unit
                closestDistance = distance
                startNewTrajectory = false
            }
        }

        // Select the correct unit, and clear its trajectory if necessary
        use unit=closest
        if startNewTrajectory {
            BeeTrajectory.Clear
        }

        // Extend trajectory
        await Subspawn {
            once ButtonUp(Click) { Expire }
            
            with Pointer {
                let snapTo = Pointer.QueryNearest(filter=Category:Bee | Category:Pollen).Pos
                let target = snapTo && Distance(snapTo, Pointer) < SnapRadius ? snapTo : Pointer
                let tail = BeeTrajectory[BeeTrajectory.Length - 1]
                if !tail || Distance(tail, target) > 0.5 {
                    BeeTrajectory.Push(target)
                    BeeTrajectoryChanged
                }
            }
        }
    }
}