java-api/build.gradle at master · quedexnet/java-api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

group 'net.quedex'
version '0.9.0'
ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

ext {
    if (!project.hasProperty('ossrhUsername')) {
        ossrhUsername = ''
    }

    if (!project.hasProperty('ossrhPassword')) {
        ossrhPassword = ''
    }
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.21'
    compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.8.0'
    compile group: 'org.bouncycastle', name: 'bcpg-jdk15on', version: '1.54'
    compile group: 'com.google.guava', name: 'guava', version: '19.0'
    compile group: 'org.java-websocket', name: 'Java-WebSocket', version: '1.3.0'

    testCompile group: 'org.testng', name: 'testng', version: '6.9.10'
    testCompile group: 'ch.qos.logback', name: 'logback-classic', version: '1.1.7'
    testCompile group: 'org.mockito', name: 'mockito-all', version: '1.10.19'
    testCompile group: 'org.assertj', name: 'assertj-core', version: '3.5.2'
    testCompile group: 'junit', name: 'junit', version: '4.12' // mockito depends on it
}

test {
    useTestNG()

    testLogging.showStandardStreams = true
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

signing {
    required { isReleaseVersion && gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment {
                MavenDeployment deployment -> signing.signPom(deployment)
            }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.project {
                name = 'java-api'
                packaging = 'pom'
                // optionally artifactId can be defined here
                description = 'Quedex Java API.'
                url = 'https://github.com/quedexnet/java-api'

                scm {
                    connection = 'scm:git:https://github.com/wgromniak/java-api.git'
                    developerConnection = 'scm:git:https://github.com/quedexnet/java-api.git'
                    url = 'https://github.com/quedexnet/java-api'
                }

                licenses {
                    license {
                        name = 'The MIT License'
                        url = 'https://opensource.org/licenses/MIT'
                    }
                }

                developers {
                    developer {
                        id = 'wgromniak'
                        name = 'Wiktor Gromniak'
                        email = 'wgromniak@quedex.net'
                        url = 'https://github.com/wgromniak'
                    }
                }
            }
        }
    }
}

wrapper {
    gradleVersion '2.14'
}