coding-exercise/build.gradle.kts at main · petrmac/coding-exercise · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
plugins {
	java
	groovy
	jacoco
	id("org.springframework.boot") version "3.3.6"
	id("io.spring.dependency-management") version "1.1.6"
	id("com.google.cloud.tools.jib") version "3.4.4"
	id("org.shipkit.shipkit-changelog") version "2.0.1"
	id("org.shipkit.shipkit-github-release") version "2.0.1"
	id("org.shipkit.shipkit-auto-version") version "2.1.0"
}

group = "com.example"

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

configurations {
	compileOnly {
		extendsFrom(configurations.annotationProcessor.get())
	}
}

repositories {
	mavenCentral()
}

extra["spockBomVersion"] = "2.4-M4-groovy-4.0"
extra["mapstructVersion"] = "1.6.2"
extra["lombokMapstructVersion"] = "0.2.0"

dependencyManagement {
	imports {
		mavenBom(("org.spockframework:spock-bom:${property("spockBomVersion")}"))
	}
}

dependencies {
	implementation("org.springframework.boot:spring-boot-starter")
	implementation("org.springframework.boot:spring-boot-starter-actuator")
	implementation("org.springframework.boot:spring-boot-starter-web")
	implementation("org.springframework:spring-webflux")

	compileOnly("org.projectlombok:lombok")

	annotationProcessor("org.projectlombok:lombok")
	annotationProcessor("org.mapstruct:mapstruct-processor:${property("mapstructVersion")}")
	annotationProcessor("org.projectlombok:lombok-mapstruct-binding:${property("lombokMapstructVersion")}")

	testAnnotationProcessor("org.mapstruct:mapstruct-processor:${property("mapstructVersion")}")

	testImplementation("org.springframework.boot:spring-boot-starter-test")
	testImplementation("org.springframework.boot:spring-boot-starter-webflux")
	testImplementation("org.testcontainers:spock")
	testImplementation("org.spockframework:spock-core")
	testImplementation("org.spockframework:spock-spring")
}

tasks.withType<Test> {
	useJUnitPlatform()
}

tasks.jacocoTestReport {
	dependsOn(tasks.test)
	reports {
		xml.required.set(true)
		csv.required.set(false)
		html.required.set(true)
	}
}

tasks.jacocoTestCoverageVerification {
	violationRules {
		rule {
			element = "CLASS"

			limit {
				counter = "LINE"
				value = "COVEREDRATIO"
				minimum = "0.95".toBigDecimal()
			}
		}
	}
}

tasks.check {
	dependsOn(tasks.jacocoTestCoverageVerification)
}