ModelIndependentFit/plot_result.plt at master · pdigiglio/ModelIndependentFit · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# Normalization factor for the guess
norm = 15.9/.9394

set grid

set terminal qt 1 size 1820, 980

set multiplot layout 2,1

set title  "Fit result of the S-wave decay cumulative phase in D^+ -> {/Symbol p}^+ {/Symbol p}^- {/Symbol p}^+"
set xlabel "Mass-bin low edge [GeV/c^2]"
set ylabel "Cumulative phase [deg]"

set autoscale
plot "par_guess.txt" using 1:6    with linespoints title "Guess cumulative phase", \
     "par_fit.txt"   using 1:6:7  with yerrorbars  title "Best fit parameters (w. error bars)", \
     "par_fit.txt"   using 1:6    with lines       notitle

set title  "Fit result of the S-wave decay phase difference in D^+ -> {/Symbol p}^+ {/Symbol p}^- {/Symbol p}^+"
set xlabel "Mass-bin low edge [GeV/c^2]"
set ylabel "Phase difference [deg]"

set autoscale
plot "par_guess.txt" using 1:4    with linespoints title "Guess phase difference", \
     "par_fit.txt"   using 1:4:5  with yerrorbars  title "Best fit parameters (w. error bars)", \
     "par_fit.txt"   using 1:4    with lines       notitle

unset multiplot

set terminal qt 2

set title  "Fit result of the S-wave decay intensity in D^+ -> {/Symbol p}^+ {/Symbol p}^- {/Symbol p}^+"
set xlabel "Mass-bin low edge [GeV/c^2]"
set ylabel "Decay intensity"

set autoscale
plot "par_fit.txt"   using 1:2           with steps       notitle, \
     "par_fit.txt"   using 1:2:3         with yerrorbars  title "Best fit parameters (w. error bars)", \
     "par_guess.txt" using 1:2           with linespoints title "Guess parameters",

     #"par_guess.txt" using 1:(norm * $2) with linespoints title "(15.9/.9394) * guess par"

set terminal qt 3

set title "Fit result of the S-wave decay intensity in D^+ -> {/Symbol p}^+ {/Symbol p}^- {/Symbol p}^+"
set xlabel "Re(bin amplitude)"
set ylabel "Im(bin amplitude)"

set autoscale
# I can't yet manage to unset this!
set size square
plot "par_guess.txt" using ($2 * cos(acos(-1) * $6 / 180)):($2 * sin(acos(-1) * $6 / 180)) with linespoints title "Guess parameters", \
     "par_fit.txt" using ($2 * cos(acos(-1) * $6 / 180)):($2 * sin(acos(-1) * $6 / 180)) with linespoints title "Fit parameters", \

unset size