JavaModulusChecker/build.gradle at master · pauldambra/JavaModulusChecker · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
group 'com.github.pauldambra'

version System.getenv("VERSION") ?: '1.1.0-SNAPSHOT'

allprojects { ext."signing.keyId" = '1FE3FC71' }
allprojects { ext."signing.secretKeyRingFile" = './secring.gpg' }
allprojects { ext."signing.password" = System.getenv("SECRING_PASSWORD") }

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'jacoco'

jacocoTestReport {
    reports {
        xml.enabled true
        html.enabled false
    }
}

check.dependsOn jacocoTestReport

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile 'com.natpryce:hamkrest:1.5.0.0'
    compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
}

tasks.withType(Jar) {
    from(project.projectDir) {
        include 'MIT-license.txt'
        into 'META-INF'
    }
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: System.getenv('SONATYPE_USERNAME'), password: System.getenv('SONATYPE_PASSWORD'))
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: System.getenv('SONATYPE_USERNAME'), password: System.getenv('SONATYPE_PASSWORD'))
            }

            pom.project {
                name 'ModulusChecker'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'Java implementation of UK Bank account Modulus Checking. Modulus Checking is a process used to determine if a given account number could be valid for a given sort code.'
                url 'https://github.com/pauldambra/JavaModulusChecker'

                scm {
                    connection 'git@github.com:pauldambra/JavaModulusChecker.git'
                    developerConnection 'git@github.com:pauldambra/JavaModulusChecker.git'
                    url 'https://github.com/pauldambra/JavaModulusChecker'
                }

                licenses {
                    license {
                        name 'MIT'
                        url 'https://github.com/pauldambra/JavaModulusChecker/blob/master/MIT-license.txt'
                    }
                }

                developers {
                    developer {
                        id 'pauldambra'
                        name 'Paul D\'Ambra'
                        email 'paul.dambra@gmail.com'
                    }
                }
            }
        }
    }
}
buildscript {
    ext.kotlin_version = '1.2.60'
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}
compileKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}
compileTestKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}