hawk/build.gradle at develop · megacool/hawk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
subprojects {
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'idea'
    apply plugin: 'signing'

    repositories {
        mavenCentral()
        mavenLocal()
    }

    dependencies {
        testCompile 'org.testng:testng:6.8'
    }

    group = 'com.wealdtech.hawk'
    version = '1.2.2'

    test {
        useTestNG()
    }

    task copyLibs (type: Copy) {
        into "$buildDir/output/libs"
        from configurations.testRuntime
    }

    task testJar (type: Jar) {
        classifier = 'tests'
        from sourceSets.test.output
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier = 'javadoc'
        from 'build/docs/javadoc'
    }

    task sourcesJar(type: Jar) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    artifacts {
        archives jar
        archives javadocJar
        archives sourcesJar
    }

    signing {
        sign configurations.archives
    }
    signArchives.onlyIf { gradle.taskGraph.hasTask(uploadArchives) }

    if (!project.hasProperty('sonatypeUsername')) {
        ext.sonatypeUsername = ''
    }
    if (!project.hasProperty('sonatypePassword')) {
        sonatypePassword = ''
    }
    uploadArchives {
        repositories {
            mavenDeployer {
                beforeDeployment {
                    MavenDeployment deployment -> signing.signPom(deployment)
                }

                repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                    authentication(userName: sonatypeUsername, password: sonatypePassword)
                }

                pom.project {
                    packaging 'jar'
                    url 'https://github.com/wealdtech/hawk'

                    scm {
                        url 'scm:git@github.com:wealdtech/hawk.git'
                        connection 'scm:git@github.com:wealdtech/hawk.git'
                        developerConnection 'scm:git@github.com:wealdtech/hawk.git'
                    }

                    licenses {
                        license {
                            name 'The Apache Software License, Version 2.0'
                            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                            distribution 'repo'
                        }
                    }

                    developers {
                        developer {
                            id 'wealdtech'
                            name 'Weald Technology'
                        }
                    }
                }
            }
        }
    }

    idea.module.iml {
        beforeMerged { module ->
            module.dependencies.clear()
        }
    }
}