linked-blocking-multi-queue/build.gradle at master · marianobarrios/linked-blocking-multi-queue · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
plugins {
    id 'java'
    id 'jvm-test-suite'
    id 'maven-publish'
    id "com.diffplug.spotless" version "7.2.1" // jrelease fails with 8.0.x
    id 'org.jreleaser' version '1.23.0'
}

group = 'com.github.marianobarrios'
version = System.getenv('VERSION')

tasks.named('compileJava') {
    options.release = 8
    // for some reason javac warns the previous option, disabling
    options.compilerArgs.add('-Xlint:all,-options')
}

tasks.named('compileTestJava') {
    options.release = 8
    // for some reason javac warns the previous option, disabling
    options.compilerArgs.add('-Xlint:all,-options')
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.14.3'
}

java {
    withSourcesJar()
    withJavadocJar()
}

var testJavaToolchain = System.getenv('TEST_JAVA_TOOLCHAIN')

testing {
    suites {
        test {
            useJUnitJupiter()
            targets {
                all {
                    testTask.configure {
                        if (testJavaToolchain != null) {
                            javaLauncher.set(
                                    javaToolchains.launcherFor {
                                        languageVersion.set(JavaLanguageVersion.of(testJavaToolchain))
                                    }
                            )
                        }
                    }
                }
            }
        }
    }
}

publishing {
    publications {
        lbmq(MavenPublication) {
            artifactId = 'lbmq'
            from components.java
            pom {
                name = 'Linked Blocking Multi-Queue'
                description = 'A concurrent collection that extends the existing Java concurrent collection library, ' +
                        'offering an optionally-bounded blocking "multi-queue" based on linked nodes.'
                url = 'https://github.com/marianobarrios/linked-blocking-multi-queue'
                licenses {
                    license {
                        name = 'BSD-style'
                        url = 'http://www.opensource.org/licenses/bsd-license.php'
                    }
                }
                developers {
                    developer {
                        name = 'Mariano Barrios'
                        email = 'marbar@gmail.com'
                    }
                }
                scm {
                    url = 'https://github.com/marianobarrios/linked-blocking-multi-queue'
                    connection = 'scm:git@github.com:marianobarrios/linked-blocking-multi-queue.git'
                    developerConnection = 'scm:git@github.com:marianobarrios/linked-blocking-multi-queue.git'
                }
            }
        }
    }
    repositories {
        maven {
            url = layout.buildDirectory.dir('staging-deploy')
        }
    }
}

jreleaser {
    signing {
        active = 'ALWAYS'
        armored = true
    }
    deploy {
        maven {
            mavenCentral {
                sonatype {
                    active = 'RELEASE'
                    url = 'https://central.sonatype.com/api/v1/publisher'
                    stagingRepository('build/staging-deploy')
                }
            }
        }
    }
}