dbcppp/CMakeLists.txt at master · guoh27/dbcppp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
cmake_minimum_required(VERSION 3.12)

project("dbcppp" VERSION 3.9.0)

# CONFIGURATION

set(CMAKE_CXX_STANDARD 17)
option(BUILD_DBCPPP_TOOLS "Build dbcppp utility application" OFF)
option(BUILD_DBCPPP_TESTS "Build tests" OFF)
option(BUILD_DBCPPP_EXAMPLES "Build examples" OFF)
option(BUILD_DBCPPP_SHARED "Build shared library" ON)

# DEPENDENCIES & Requirements

find_package(Boost REQUIRED CONFIG)


# CREATE LIBRARY

file(GLOB include "include/dbcppp/*.h")
file(GLOB headers "src/*.h")
file(GLOB sources "src/*.cpp")

if(BUILD_DBCPPP_SHARED)
    add_library(${PROJECT_NAME} SHARED ${include} ${headers} ${sources})
else()
    add_library(${PROJECT_NAME} STATIC ${include} ${headers} ${sources})
endif(BUILD_DBCPPP_SHARED)

add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS ${PROJECT_NAME})

if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
    # https://en.cppreference.com/w/cpp/filesystem
    if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "9.1")
        target_link_libraries(${PROJECT_NAME} PRIVATE stdc++fs)
    endif()
endif()

# CONFIGURE LIBRARY

target_compile_options(${PROJECT_NAME} PRIVATE -Wno-switch)

set_target_properties(${PROJECT_NAME} PROPERTIES
    SOVERSION ${PROJECT_VERSION}
    PUBLIC_HEADER "${include}"
)

target_include_directories(${PROJECT_NAME} PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/dbcppp>
    $<INSTALL_INTERFACE:include/dbcppp>
    include/
)

# INSTALL LIBRARY

install(TARGETS ${PROJECT_NAME}
    RUNTIME DESTINATION bin
    LIBRARY DESTINATION lib
    ARCHIVE DESTINATION lib
    PUBLIC_HEADER DESTINATION include/dbcppp
)


# ADDITIONAL: Tools, Tests & Examples

if (BUILD_DBCPPP_TOOLS)
    add_subdirectory(tools/dbcppp)
endif()

if (BUILD_DBCPPP_TESTS)
  add_subdirectory(tests)
endif()

if (BUILD_DBCPPP_EXAMPLES)
  add_subdirectory(examples)
endif()

# PACKAGE (useful for debugging install, use make package)

set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY NO)
set(CPACK_VERBATIM_VARIABLES YES)
set(CPACK_SOURCE_GENERATOR "TGZ")
set(CPACK_SOURCE_IGNORE_FILES \\.git/ build/ ".*~$")
include(CPack)