build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.4.0'
    id 'io.spring.dependency-management' version '1.1.6'
    id 'checkstyle'
    id 'jacoco'
    id 'com.diffplug.spotless' version '6.25.0'
    id 'org.sonarqube' version '7.2.0.6526'
}

group = 'com.project'
version = '0.0.1-SNAPSHOT'

// ============================================================================
// Coverage Exclusion Patterns (공통 제외 패턴)
// ============================================================================
def coverageExcludePackages = [
    '**',                // TODO: 1차 개발 완료 후 제거
    '**/config/**',      // Config 클래스 제외
    '**/exception/**',   // Exception 클래스 제외
    '**/dto/**',         // DTO 클래스 제외
]

// JaCoCo용 제외 패턴 (클래스 파일)
def jacocoCoverageExcludes = coverageExcludePackages + ['**/*Application.class']

// Sonar용 제외 패턴 (소스 파일)
def sonarCoverageExcludes = coverageExcludePackages.collect { it + '/*.java' } + ['**/Application.java']

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

// OpenTelemetry BOM for consistent versions
dependencyManagement {
    imports {
        mavenBom 'io.opentelemetry:opentelemetry-bom:1.44.1'
        mavenBom 'io.opentelemetry.instrumentation:opentelemetry-instrumentation-bom-alpha:2.11.0-alpha'
    }
}

dependencies {
    // Spring Boot
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'

    // Monitoring & Observability - OpenTelemetry (traces, logs)
    implementation 'io.opentelemetry.instrumentation:opentelemetry-spring-boot-starter'
    implementation 'io.opentelemetry.instrumentation:opentelemetry-logback-appender-1.0'

    // Micrometer - Prometheus (local scraping) + OTLP (push to Alloy)
    implementation 'io.micrometer:micrometer-registry-prometheus'
    implementation 'io.micrometer:micrometer-registry-otlp'
    implementation 'com.google.protobuf:protobuf-java:3.25.5'

    // Structured logging
    implementation 'net.logstash.logback:logstash-logback-encoder:7.4'

    // Database
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    runtimeOnly 'com.mysql:mysql-connector-j'
    implementation 'org.springframework.kafka:spring-kafka'
    implementation 'com.github.da-bom:lib-kafka:v1.0.1'

    // Flyway
    implementation 'org.flywaydb:flyway-core'
    implementation 'org.flywaydb:flyway-mysql'

    // QueryDSL
    implementation 'com.querydsl:querydsl-jpa:5.1.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:5.1.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // Swagger
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.7.0'

    // Lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // jwt
    implementation "io.jsonwebtoken:jjwt-api:0.11.2"
    runtimeOnly "io.jsonwebtoken:jjwt-impl:0.11.2"
    runtimeOnly "io.jsonwebtoken:jjwt-jackson:0.11.2"

    //BCrypt
    implementation 'org.mindrot:jbcrypt:0.4'

    // AWS SDK v2 - S3 (R2 compatible)
    implementation platform('software.amazon.awssdk:bom:2.25.70')
    implementation 'software.amazon.awssdk:s3'

    // Test
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testImplementation 'org.springframework.kafka:spring-kafka-test'
    testRuntimeOnly 'com.h2database:h2'
}

// ============================================================================
// bootRun (.env 파일에서 환경변수 로딩)
// ============================================================================
bootRun {
    def envFile = rootProject.file('.env')
    if (envFile.exists()) {
        envFile.readLines().each { line ->
            line = line.trim()
            if (line && !line.startsWith('#') && line.contains('=')) {
                def (key, value) = line.split('=', 2)
                environment key.trim(), value.trim()
            }
        }
    }
}

// ============================================================================
// Test
// ============================================================================
tasks.named('test') {
    useJUnitPlatform()
    finalizedBy jacocoTestReport, jacocoTestCoverageVerification
}

// ============================================================================
// JaCoCo (Code Coverage)
// ============================================================================
jacoco {
    toolVersion = '0.8.12'
}

jacocoTestReport {
    dependsOn test
    reports {
        xml.required = true
        html.required = true
    }
    afterEvaluate {
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it, exclude: jacocoCoverageExcludes)
        }))
    }
}

jacocoTestCoverageVerification {
    dependsOn jacocoTestReport

    afterEvaluate {
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it, exclude: jacocoCoverageExcludes)
        }))
    }

    violationRules {
        rule {
            limit {
                minimum = 0.0
            }
        }
    }

    // 검사할 클래스가 없으면 커버리지 검증 건너뛰기
    doFirst {
        def hasClasses = classDirectories.files.any { dir ->
            dir.exists() && fileTree(dir: dir, exclude: jacocoCoverageExcludes).files.size() > 0
        }
        if (!hasClasses) {
            println "No classes to verify coverage. Skipping jacocoTestCoverageVerification."
            throw new StopExecutionException()
        }
    }
}

// ============================================================================
// Checkstyle (Code Style) - Naver Conventions
// ============================================================================
checkstyle {
    toolVersion = '10.21.4'
    configFile = file("${rootDir}/config/checkstyle/checkstyle.xml")
    configDirectory = file("${rootDir}/config/checkstyle")
    ignoreFailures = false
    maxWarnings = 0
}

// ============================================================================
// Spotless (Code Formatting) - 4-space indentation, Naver import order
// ============================================================================
spotless {
    java {
        target 'src/*/java/**/*.java'
        googleJavaFormat().aosp().reflowLongStrings()
        // Naver convention import order: java -> javax -> jakarta -> org -> net -> com -> others -> lombok
        importOrder('java', 'javax', 'jakarta', 'org', 'net', 'com', '', 'lombok')
        trimTrailingWhitespace()
        endWithNewline()
    }
}

// ============================================================================
// SonarQube (Self-Hosted)
// ============================================================================
sonar {
    properties {
        property 'sonar.projectKey', 'dabom-api-core'
        property 'sonar.projectName', 'dabom-api-core'
        // Java 분석을 위한 바이너리 경로
        property 'sonar.java.binaries', 'build/classes/java/main'
        property 'sonar.java.libraries', "${System.getProperty('user.home')}/.gradle/caches/**/modules-*/files-*/**/*.jar"
        // JaCoCo 커버리지
        property 'sonar.java.coveragePlugin', 'jacoco'
        property 'sonar.coverage.jacoco.xmlReportPaths', 'build/reports/jacoco/test/jacocoTestReport.xml'
        property 'sonar.coverage.exclusions', sonarCoverageExcludes.join(',')
    }
}