Check during configure whether decode() returns an Instruction::Ptr or an Instruction

Author: clementFoyer

config/macros.m4

@@ -1856,6 +1856,40 @@ AC_DEFUN([AX_PROG_DYNINST],
       CPPFLAGS="${CPPFLAGS} -I${DYNINST_INCLUDES} -I${BOOST_HOME}/include"
       AC_CHECK_HEADERS([BPatch.h], [], [DYNINST_INSTALLED="no"])
 
+      AC_MSG_CHECKING([whether DynInst uses Instruction::Ptr])
+      AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM(
+            [[#include <InstructionDecoder.h>]],
+            [[
+                InstructionAPI::InstructionDecoder dec((unsigned char*)nullptr,0,Arch_x86);
+                InstructionAPI::Instruction insn = dec.decode();
+                insn.isValid();
+            ]]
+         )
+        ],
+        [dyninst_decode_returns_instr_ptr="no"],
+        [AC_COMPILE_IFELSE(
+           [AC_LANG_PROGRAM(
+               [[#include <InstructionDecoder.h>]],
+               [[
+                   InstructionAPI::InstructionDecoder dec((unsigned char*)nullptr,0,Arch_x86);
+                   InstructionAPI::Instruction::Ptr insn = dec.decode();
+                   insn->isValid();
+               ]]
+            )
+           ],
+           [dyninst_decode_returns_instr_ptr="yes"],
+           [dyninst_decode_returns_instr_ptr="unknown"]
+         )
+        ]
+      )
+      AC_MSG_RESULT([$dyninst_decode_returns_instr_ptr])
+      AS_IF([test "$dyninst_decode_returns_instr_ptr" = "yes"],
+            [AC_DEFINE([DYNINST_DECODE_RETURNS_PTR], 1, [Define to 1 if DYNINST decoder's function decode() return value is of type Intruction::Ptr])],
+            [test "$dyninst_decode_returns_instr_ptr" = "unknown"],
+            [AC_MSG_ERROR([Unable to determine whether DynInst uses Instruction::Ptr or not])]
+      )
+
       AC_SUBST(DYNINST_CXXFLAGS)
       AC_SUBST(DYNINST_CPPFLAGS)
 

src/launcher/dyninst/commonSnippets.C

@@ -482,10 +482,17 @@ string decodeBasicBlocks(BPatch_function * function, string routine)
         ParseAPI::Block* b  = ParseAPI::convert(block);
         void * buf  = b->region()->getPtrToInstruction(b->start());
         InstructionAPI::InstructionDecoder dec((unsigned char*)buf,b->size(),b->region()->getArch());
+#if defined(DYNINST_DECODE_RETURNS_PTR)
+        InstructionAPI::Instruction::Ptr insn;
+        while((insn = dec.decode())) {
+            res <<loop_name<<"# "<<line++<<": "<< insn->format() << endl;
+        }
+#else
         InstructionAPI::Instruction insn;
         while((insn = dec.decode()).isValid()) {
             res <<loop_name<<"# "<<line++<<": "<< insn.format() << endl;
         }
+#endif // defined(DYNINST_DECODE_RETURNS_PTR)
     }
     return res.str();
 }