ConfiguredLib/build.gradle at master · Zeitheron/ConfiguredLib · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
plugins {
    id 'java'
    id 'maven-publish'
}

group 'org.zeith'

repositories {
    mavenCentral()
    maven {
        name = "Zeitheron Maven"
        url = "https://maven.zeith.org"
    }
}

dependencies {
    implementation "org.zeith.libs:TupleLib:$tuple_lib"

    testImplementation platform('org.junit:junit-bom:5.10.0')
    testImplementation 'org.junit.jupiter:junit-jupiter'
}

test {
    useJUnitPlatform()
}

tasks.register('shadedJar', Jar) {
    manifest.from jar.manifest
    classifier = 'shaded'
    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    } {
        exclude "META-INF/*.SF"
        exclude "META-INF/*.DSA"
        exclude "META-INF/*.RSA"
    }
    with jar
}

tasks.register('srcJar', Jar) {
    dependsOn classes
    from sourceSets.main.allSource
    classifier = 'sources'
}

tasks.register('javadocJar', Jar) {
    dependsOn classes
    from javadoc
    classifier = 'javadoc'
}

artifacts {
    archives shadedJar
    archives srcJar
    archives javadocJar
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = 'org.zeith.libs'
            artifactId = 'Configured'
            from components.java

            pom {
                name = 'Configured'
                description = 'Configuration library.'
                dependencies {
                    implementation "org.zeith.libs:TupleLib:$tuple_lib"
                }
            }

            artifact srcJar
            artifact javadocJar
        }
    }
    repositories {
        maven {
            url System.env.MAVEN_URL
        }
    }
}