StreamlineDiscord/build.gradle at master · Streamline-Essentials/StreamlineDiscord · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
plugins {
    id 'java'
    id 'com.gradleup.shadow' version "8.3.6" // for shadowing
    id 'io.freefair.lombok' version '8.10.2'
}

group properties['group']
version properties['version']

ext {
    jdaVersion = "6.3.1"

    deps = ""
    StringBuilder builder = new StringBuilder()

    int i = 0
    List<String> list = properties['pf.dependencies'].toString().split(", ")
    for (String s : list) {
        if (i == list.size() - 1) {
            builder.append(s)
        } else {
            builder.append(s).append(", ")
        }
        i ++
    }

    deps = builder.toString()

    needs_bapi = false

    String include_bapi = rootProject.properties.get('include-bapi', "false");

    if (include_bapi.toBoolean()) {
        needs_bapi = true
    }
}

repositories {
    mavenCentral()
    maven { url = 'https://oss.sonatype.org/content/repositories/snapshots' }
    maven { url = 'https://oss.sonatype.org/content/repositories/central' }

    // Spigot / Bukkit
    maven {
        url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'
        content {
            includeGroup 'org.bukkit'
            includeGroup 'org.spigotmc'
        }
    }

    // StreamlineCore - CodeMC
    maven {
        name = "streamline-essentials"
        url = "https://repo.codemc.org/repository/streamline-essentials/"
    }

    // JitPack
    maven { url = 'https://jitpack.io' }
}

dependencies {
    // Spigot / Bukkit
    compileOnly 'org.spigotmc:spigot-api:1.20.4-R0.1-SNAPSHOT'

    // LuckPerms
    compileOnly 'net.luckperms:api:5.4'

    // StreamlineCore
    boolean includeBapi = rootProject.properties['include-bapi'].toString().toBoolean()
    if (includeBapi) {
        // BukkitOfUtils
        annotationProcessor(compileOnly('gg.drak:BukkitOfUtils:1.18.0'))

        annotationProcessor(compileOnly("gg.drak:StreamlineCore-BAPI:${rootProject.properties['streamline.version'] ?: '2.5.5.7'}"))
    } else {
        // TheBase
        annotationProcessor(compileOnly("gg.drak:TheBase:1.0.0"))

        annotationProcessor(compileOnly("gg.drak:StreamlineCore-API:${rootProject.properties['streamline.version'] ?: '2.5.5.7'}"))
    }

    // JDA
    shadow(implementation("net.dv8tion:JDA:$jdaVersion") { // replace $version with the latest version
        // Optionally disable audio natives to reduce jar size by excluding opus-java
        // Gradle DSL:
        exclude module: 'opus-java'
        exclude group: 'org.slf4j'
        // Kotlin DSL:
        // exclude(module="opus-java")
    })
    shadow(implementation("club.minnced:discord-webhooks:0.8.4") {
        exclude group: "org.slf4j"
    })

    compileOnly("com.github.Streamline-Essentials:StreamlineMessaging:master-SNAPSHOT")
    compileOnly("com.github.Streamline-Essentials:StreamlineGroups:master-SNAPSHOT")

    shadow(implementation("ch.qos.logback:logback-classic:1.5.6"))
}

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

shadowJar {
    manifest {
        attributes 'Plugin-Class': rootProject.properties['pf.class'].toString() + '.' + rootProject.name.toString()
        attributes 'Plugin-Id': rootProject.properties['pf.id'].toString()
        attributes 'Plugin-Version': rootProject.version.toString()
        attributes 'Plugin-Requires': ( rootProject.properties['pf.requires'].toString() == 'none' ? '' : rootProject.properties['pf.requires'].toString() )
        attributes 'Plugin-Dependencies': ( rootProject.properties['pf.dependencies'].toString() == 'none' ? '' : rootProject.ext.deps )
        attributes 'Plugin-Description': rootProject.properties['pf.description'].toString()
        attributes 'Plugin-Provider': rootProject.properties['pf.provider'].toString()
        attributes 'Plugin-License': rootProject.properties['pf.license'].toString()
    }

    setArchiveFileName(archiveBaseName.get() + '-' + archiveVersion.get() + '.' + archiveExtension.get())
}

artifacts {
    archives shadowJar
}

wrapper {
    gradleVersion = '8.6'
    distributionType = Wrapper.DistributionType.BIN
}