StickyNoteTemplate/build.gradle.kts at master · Sayan-Development/StickyNoteTemplate · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
import net.minecrell.pluginyml.bukkit.BukkitPluginDescription
import org.sayandev.plugin.StickyNoteModules
import xyz.jpenilla.runpaper.task.RunServer
import kotlin.jvm.java

plugins {
    java
    kotlin("jvm") version "2.1.10"
    id("java-library")
    id("xyz.jpenilla.run-paper") version "2.3.1"
    id("net.minecrell.plugin-yml.bukkit") version "0.6.0"
    id("org.sayandev.stickynote.project")
}

val slug = rootProject.name.lowercase()
group = "org.sayandev"
version = "1.0.0-SNAPSHOT"

stickynote {
    modules(StickyNoteModules.CORE, StickyNoteModules.BUKKIT)
    relocate(!gradle.startParameter.taskNames.any { it.startsWith("runServer") })
}

repositories {
    mavenCentral()
    mavenLocal()

    maven("https://repo.sayandev.org/snapshots")
    maven("https://repo.sayandev.org/releases")
    maven("https://repo.sayandev.org/private")
    //PlaceholderApi
    maven("https://repo.extendedclip.com/content/repositories/placeholderapi/")
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:1.20.6-R0.1-SNAPSHOT")

    compileOnly("me.clip:placeholderapi:2.11.6")

    compileOnly(fileTree("libs"))
}

tasks {
    shadowJar {
        archiveFileName.set("${rootProject.name}-${version}.jar")
        archiveClassifier.set(null as String?)
        destinationDirectory.set(file(rootProject.projectDir.path + "/bin"))
        manifest {
            attributes["paperweight-mappings-namespace"] = "mojang"
        }
    }

    withType(RunServer::class.java) {
        downloadPlugins {
            modrinth("viaversion", "5.0.3")
            modrinth("essentialsx", "2.20.1")
            hangar("placeholderapi", "2.11.6")
            url("https://download.luckperms.net/1567/bukkit/loader/LuckPerms-Bukkit-5.4.150.jar")
            url("https://github.com/MilkBowl/Vault/releases/download/1.7.3/Vault.jar")
            url("https://ci.lucko.me/job/spark/471/artifact/spark-bukkit/build/libs/spark-1.10.123-bukkit.jar")
        }
    }

    runServer {
        minecraftVersion("1.20.6")

        javaLauncher = project.javaToolchains.launcherFor {
            vendor = JvmVendorSpec.JETBRAINS
            languageVersion = JavaLanguageVersion.of("17")
        }

        jvmArgs("-XX:+AllowEnhancedClassRedefinition")
    }

    compileJava {
        options.encoding = Charsets.UTF_8.name()
    }

    build {
        dependsOn(shadowJar)
    }

    processResources {
        filesMatching(listOf("**plugin.yml", "**plugin.json")) {
            expand(
                "version" to project.version as String,
                "slug" to slug,
                "name" to rootProject.name,
                "description" to project.description
            )
        }
    }
}

bukkit {
    name = project.name
    version = project.version as String
    description = project.description
    website = "https://sayandev.org"
    author = "SayanDevelopment"

    main = "${project.group}.${project.name.lowercase()}.${project.name}"

    apiVersion = "1.13"

    softDepend = listOf(
        "PlaceholderAPI"
    )
}