linux-nitrosense-rust/flake.nix at master · Packss/linux-nitrosense-rust · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
{
  description = "Acer NitroSense for Linux (Rust)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
      in
      {
        packages.default = pkgs.rustPlatform.buildRustPackage {
          pname = "linux-nitrosense";
          version = "0.1.0";

          src = ./.;

          cargoLock = {
            lockFile = ./Cargo.lock;
          };

          nativeBuildInputs = [
            pkgs.pkg-config
            pkgs.wrapGAppsHook4
            pkgs.rustPlatform.bindgenHook
          ];

          buildInputs = [
            pkgs.glib
            pkgs.gtk4
            pkgs.libadwaita
            pkgs.gsettings-desktop-schemas
          ];

          postInstall = ''
            install -D -m 644 linux-nitrosense.desktop $out/share/applications/linux-nitrosense.desktop
            install -D -m 644 linux-nitrosense.service $out/lib/systemd/system/linux-nitrosense.service
          '';

          meta = with pkgs.lib; {
            description = "Acer NitroSense fan/power/keyboard control for Linux";
            license = licenses.mit;
            maintainers = [ ];
          };
        };

        apps.default = flake-utils.lib.mkApp {
          drv = self.packages.${system}.default;
        };

        devShells.default = pkgs.mkShell {
          nativeBuildInputs = [
            pkgs.pkg-config
            pkgs.wrapGAppsHook4
          ];
          buildInputs = [
            pkgs.rustc
            pkgs.cargo
            pkgs.rustfmt
            pkgs.libclang
            pkgs.clippy
            pkgs.gtk4
            pkgs.glib
            pkgs.gsettings-desktop-schemas
          ];

          shellHook = ''
            export XDG_DATA_DIRS=$XDG_DATA_DIRS:${pkgs.gsettings-desktop-schemas}/share/gsettings-schemas/${pkgs.gsettings-desktop-schemas.name}:${pkgs.gtk4}/share/gsettings-schemas/${pkgs.gtk4.name}
            echo "NitroSense Rust dev shell"
          '';
        };
      }
    )
    // {
      nixosModules.default =
        {
          config,
          lib,
          pkgs,
          ...
        }:
        let
          cfg = config.services.linux-nitrosense;
        in
        {
          options.services.linux-nitrosense = {
            enable = lib.mkEnableOption "Acer NitroSense Service";
          };

          config = lib.mkIf cfg.enable {
            environment.systemPackages = [
              self.packages.${pkgs.system}.default
              pkgs.gsettings-desktop-schemas
              pkgs.gtk4
            ];

            systemd.services.linux-nitrosense = {
              description = "NitroSense Service";
              wantedBy = [ "multi-user.target" ];
              serviceConfig = {
                ExecStart = "${self.packages.${pkgs.system}.default}/bin/linux-nitrosense --daemon";
                Restart = "on-failure";
                Type = "simple";
                User = "root";
              };
            };
          };
        };
    };
}