lambda-base/build.gradle at master · Oulumo/lambda-base · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
ext {
    versionMajor = 0
    versionMinor = 14
    versionPoint = 0
}

buildscript {
    ext {
        logbackLoglevel='DEBUG'

        gsonVersion='2.8.0'
        joda_time_version='2.9.4'
        commonsIoVersion='2.5'
        slf4jVersion='1.7.25'
        logbackVersion='1.2.3'
        daggerVersion='2.10'

        awsLambdaCoreVersion='1.1.0'
        awsLambdaEventsVersion='1.3.0'
        awsJavaSdkVersion='1.11.136'

        jUnitVersion='4.12'
        hamcrestVersion='1.3'
    }
    repositories {
	    jcenter()
    }
    dependencies {
        classpath "net.sf.gapt:apt:1"
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3'
    }
}

allprojects {
    group 'fi.oulumo.lambda'
    version computeVersion()

    repositories {
	    jcenter()
    }
}

subprojects {
    ext {
        asciiDocOutputDir = file("${buildDir}/asciidoc")
    }

    apply plugin: 'maven'
    apply plugin: 'java'
    apply plugin: "net.sf.gapt"

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    test {
        testLogging {
            exceptionFormat = 'full'
        }
    }

    compileJava.dependsOn(processResources)

    processResources {
        filesMatching('**/logback.xml') {
            filter {
                it.replace('${logback.loglevel}', logbackLoglevel)
            }
        }
    }
}

configure(subprojects - project(':lambda-base-example')) {
    apply plugin: 'com.jfrog.bintray'

    task sourceJar(type: Jar) {
        from sourceSets.main.allSource
        classifier = 'sources'
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        from javadoc.destinationDir
        classifier = 'javadoc'
    }

    // Add the sourceJars to non-extractor modules
    artifacts {
        archives jar
        archives sourceJar
        archives javadocJar
    }

    bintray {
        user = "${bintray_user}"
        key = "${bintray_apikey}"
        configurations = ['archives']
        dryRun = !(project.hasProperty('pushBintray'))
        publish = true
        override = true

        pkg {
            repo = 'lambda-base'
            name = "fi.oulumo.lambda:${project.name}"
            desc = "${project.name}"
            labels = ['lambda', 'aws-lambda', 'serverless']
            publicDownloadNumbers = true

            githubRepo = 'Oulumo/lambda-base'
            githubReleaseNotesFile = 'README.adoc'

            version {
                name = computeVersion()
                released  = new Date()
                licenses = ['Apache-2.0']
                websiteUrl = 'https://github.com/Oulumo/lambda-base'
                issueTrackerUrl = 'https://github.com/Oulumo/lambda-base/issues'
                vcsUrl = 'https://github.com/Oulumo/lambda-base.git'
            }
        }
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '3.5'
}

def computeVersion() {
    // Version format: <major>.<minor>.<point>.<build>
    return String.format('%d.%d.%d.%d', versionMajor, versionMinor, versionPoint, getBuildNumber())
}

def getBuildNumber() {
    return Integer.valueOf(System.env.BUILD_NUMBER ?: (System.env.BUILDKITE_BUILD_NUMBER ?: 0))
}