CMakeLists.txt

cmake_minimum_required(VERSION 3.30...4.2)

project(incplot
    HOMEPAGE_URL "https://github.com/InCom-0/incplot"
    VERSION "1.0.2"
    DESCRIPTION
    "CLI tool for drawing great looking plots in the terminal focused on user ergonomics and simplicity."
    LANGUAGES CXX)

set(CMAKE_CXX_SCAN_FOR_MODULES OFF)
option(BUILD_SHARED_LIBS "Build shared libraries" OFF)

option(CPM_USE_LOCAL_PACKAGES "Use local (usually system installed) packages for dependencies." ON)
option(CPM_LOCAL_PACKAGES_ONLY "Forbid the build system from downloading missing dependencies." OFF)

option(incplot_STAGE_OUTPUTS "Stage build output artifacts into proper directory structure" ON)
option(incplot_PORTABLE_LAYOUT "Use flat (Windows-like / portable) install layout" OFF)

option(incplot_CPR_USE_SYSTEM_CURL "Incplot transitively needs libcurl. Set to ON if you have and want to use system installed one" OFF)


#####################################################################
### Staging and Install dirs setting ###
#####################################################################
include(cmake/incom/StageOutputs.cmake)
include(cmake/incom/MingwRuntimeDeps.cmake)

include(GNUInstallDirs)
set(incplot_PORTABLE_LAYOUT_INSTALL_DIR "/" CACHE PATH "Dir under prefix to install to in portable layout mode")

if(incplot_STAGE_OUTPUTS)
    stageOutputDirs(${PROJECT_NAME} ${incplot_PORTABLE_LAYOUT})
endif()


#####################################################################
### Platform specifics + hacks + LTO ###
#####################################################################
if(CMAKE_CXX_COMPILER_FRONTEND_VARIANT MATCHES "MSVC")
    add_compile_options(/utf-8)
    add_compile_definitions(NOMINMAX)
endif()


### This attempts to compile sample program to find out if we are using libc++(USING_LIBCXX) or libstdc++(USING_LIBSTDCXX) or MSVC_STL(USING_MSVC_STL)
include(cmake/incom/StdlibQuery.cmake)

include(CheckIPOSupported)
check_ipo_supported(RESULT INCPLOT_LTO OUTPUT INCPLOT_LTO_OUTPUT)

# Enable LTO if supported and only when NOT in debug mode
if(INCPLOT_LTO)
    message(STATUS "LTO is supported")
    if(CMAKE_BUILD_TYPE STREQUAL "Debug")
        set(CMAKE_INTERPROCEDURAL_OPTIMIZATION FALSE)
        message(STATUS "LTO is disabled because of Debug build")
    elseif(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
        set(CMAKE_INTERPROCEDURAL_OPTIMIZATION FALSE)
        message(STATUS "LTO is disabled on MacOS")
    else()
        set(CMAKE_INTERPROCEDURAL_OPTIMIZATION FALSE)
        message(STATUS "LTO is enabled")
        # set_property(TARGET foo PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
    endif()

else()
    message(WARNING "LTO is NOT supported: ${INCPLOT_LTO_OUTPUT}")
endif()


######################################################################
### Target specification ###
######################################################################
add_executable(incplot)
target_sources(incplot PRIVATE src/main.cpp src/config.cpp src/args.cpp)
target_sources(incplot
    PRIVATE
    FILE_SET priv_headers
    TYPE HEADERS
    BASE_DIRS
    include)

set(INCPLOT_GENERATED_CONFIG_DIR "${CMAKE_CURRENT_BINARY_DIR}/generated")
include(cmake/config/configScript.cmake)

target_sources(incplot
    PRIVATE
    FILE_SET priv_auto_config
    TYPE HEADERS
    BASE_DIRS
    "${INCPLOT_GENERATED_CONFIG_DIR}")


target_compile_features(incplot PRIVATE cxx_std_23)

# TODO: Need to finish the script that drives this
# if(MINGW)
#     add_mingw_runtime_deps(incplot)
# endif(MINGW)


##########################################################################
### Settings the right options for linking for Windows and Apple  ###
##########################################################################
if(CMAKE_BUILD_TYPE STREQUAL "Release")
    if(CMAKE_SYSTEM_NAME MATCHES "Windows")
        set(BUILD_SHARED_LIBS OFF)
        if(USING_LIBSTDCXX)
            target_link_options(incplot PUBLIC -static)
        elseif(USING_LIBCXX)
            target_link_options(incplot PUBLIC -stdlib=libc++ -static)
        elseif(USING_MSVC_STL)
        endif()

    elseif(APPLE)
        if(USING_LIBSTDCXX)
            target_link_options(incplot PUBLIC -static)
        elseif(USING_LIBCXX)
            target_link_options(incplot PUBLIC -stdlib=libc++)
        elseif(USING_MSVC_STL)
            message(FATAL_ERROR "CMake reports we are using MSVC STL on APPLE platform. That is impossible.")
        endif()
    else()
    endif()

elseif(CMAKE_BUILD_TYPE STREQUAL "Debug")
endif()


##########################################################################
### Dependencies and library linking  ###
##########################################################################
include(CMake_dependencies.cmake) ### Loads and declares the required external libraries using CPM or CMake's FetchContent.

target_link_libraries(incplot PRIVATE incplot-lib::incplot-lib incfontdisc::incfontdisc)
target_link_libraries(incplot PRIVATE sqlpp23::sqlpp23 sqlpp23::sqlite3)
target_link_libraries(incplot PRIVATE argparse::argparse cpr::cpr indicators::indicators)
target_link_libraries(incplot PRIVATE LibArchive::LibArchive)
target_link_libraries(incplot PRIVATE ots::ots)

if(USING_LIBSTDCXX)
    target_link_libraries(incplot PRIVATE "-lstdc++exp")
endif()

if(NOT BUILD_SHARED_LIBS)
    target_compile_definitions(incplot PRIVATE LIBARCHIVE_STATIC)
endif()

# TODO: Figure out how to silence that warning on MinGW ... does not work like it is below
# if(SQLite3_ADDED)
#     set(sqlite3c_FILE "${CMAKE_BINARY_DIR}/_deps/sqlite3_ext-src/sqlite3.c")
#     set_source_files_properties(
#         ${sqlite3c_FILE}
#         PROPERTIES
#         COMPILE_OPTIONS "$<$<CXX_COMPILER_ID:GNU,Clang,AppleClang>:-Wno-stringop-overread>"
#     )
#     unset(sqlite3c_FILE)

# endif()


############################################################################################
### Automatic copying certain assets to build directory (mimic structure as installed)   ###
############################################################################################
if(incplot_PORTABLE_LAYOUT)
    add_custom_command(TARGET incplot POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E echo "Recreating portable installation file structure in build staging directory"

        COMMAND ${CMAKE_COMMAND} -E copy_directory_if_different
        "${CMAKE_SOURCE_DIR}/data/"
        "${${PROJECT_NAME}_STAGEDIR}/${incplot_PORTABLE_LAYOUT_INSTALL_DIR}"

        COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "${CMAKE_SOURCE_DIR}/README.md"
        "${${PROJECT_NAME}_STAGEDIR}/${incplot_PORTABLE_LAYOUT_INSTALL_DIR}/README.md"

        COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "${CMAKE_SOURCE_DIR}/LICENSE.txt"
        "${${PROJECT_NAME}_STAGEDIR}/${incplot_PORTABLE_LAYOUT_INSTALL_DIR}/LICENSE.txt"
    )

else()
    ### '.incplot-dev-build' gets created next to the binary in 'CMAKE_RUNTIME_OUTPUT_DIRECTORY'
    ### The above enables running incplot from inside build directory (without installing it)
    add_custom_command(TARGET incplot POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E echo "Recreating GNUInstallDirs installation file structure in build staging directory"
        COMMAND ${CMAKE_COMMAND} -E touch "$<TARGET_FILE_DIR:incplot>/.incplot-dev-build"

        COMMAND ${CMAKE_COMMAND} -E copy_directory_if_different
        "${CMAKE_SOURCE_DIR}/data/"
        "${${PROJECT_NAME}_STAGEDIR}/${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}"

        COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "${CMAKE_SOURCE_DIR}/README.md"
        "${${PROJECT_NAME}_STAGEDIR}/${CMAKE_INSTALL_DOCDIR}/README.md"

        COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "${CMAKE_SOURCE_DIR}/LICENSE.txt"
        "${${PROJECT_NAME}_STAGEDIR}/${CMAKE_INSTALL_DATAROOTDIR}/licenses/${PROJECT_NAME}/LICENSE.txt"
    )
endif()


########################################################
### Install specification ###
########################################################
if(incplot_PORTABLE_LAYOUT)
    install(TARGETS incplot
        RUNTIME DESTINATION ${incplot_PORTABLE_LAYOUT_INSTALL_DIR}
    )
    install(FILES $<TARGET_RUNTIME_DLLS:incplot>
        DESTINATION ${incplot_PORTABLE_LAYOUT_INSTALL_DIR}
        OPTIONAL
    )

    install(FILES data/configDB.seed.sqlite DESTINATION "${incplot_PORTABLE_LAYOUT_INSTALL_DIR}")
    install(FILES README.md DESTINATION ${incplot_PORTABLE_LAYOUT_INSTALL_DIR})
    install(FILES LICENSE.txt DESTINATION "${incplot_PORTABLE_LAYOUT_INSTALL_DIR}")

else()
    install(TARGETS incplot
        RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
    )
    install(FILES $<TARGET_RUNTIME_DLLS:incplot>
        DESTINATION ${CMAKE_INSTALL_BINDIR}
        OPTIONAL
    )

    install(FILES data/configDB.seed.sqlite DESTINATION "${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/")
    install(FILES README.md DESTINATION ${CMAKE_INSTALL_DOCDIR})
    install(FILES LICENSE.txt DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/licenses/${PROJECT_NAME}/")
endif()


if(PROJECT_IS_TOP_LEVEL)
    add_subdirectory(cmake/packaging)
endif()