cavityflow/read.f at main · Code-Sample-Collection/cavityflow · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
C     This program reads the binary streamfunction and vorticity data
C     of the driven cavity flow, obtained by solving the Fourth Order
C     Navier-Stokes equations using Erturk method. It also calculates
C     the maximum absolute residuals of the governing equations in the
C     computational domain.
C     Visit http://www.cavityflow.com
C
C     s(i,j) ==> streamfunction variable
C     v(i,j) ==> vorticity variable
C     x(i)   ==> x-coordinate
C     y(j)   ==> y-coordinate
C     dx=dy  ==> delta x = delta y = grid spacing
C     Re     ==> Reynolds Number


      program main

      implicit double precision (a-h,o-z)

      parameter(idim=600,jdim=600)

      common / flow variables /
     >s(0:idim,0:jdim),v(0:idim,0:jdim)

      common / geometry /
     >x(0:idim),y(0:jdim)

      dx=1.d0/dble(idim)
      dy=1.d0/dble(jdim)

      do 1 i=0,idim
      x(i)=dble(i)/dble(idim)
 1    continue

      do 2 j=0,jdim
      y(j)=dble(j)/dble(jdim)
 2    continue

      open(1,file='hoc_Re20000.bin',FORM='BINARY')
      read(1) Re
      do 3 i=0,idim
      do 3 j=0,jdim
      read(1) s(i,j),v(i,j)
 3    continue
      close(1)

      error_s_1=0.d0
      error_v_1=0.d0

      do 4 i=1,idim-1
      do 4 j=1,jdim-1

      A=-(dx**2./12.d0)*((v(i-1,j)-2.d0*v(i,j)+v(i+1,j))/dx**2.)
     >  -(dy**2./12.d0)*((v(i,j-1)-2.d0*v(i,j)+v(i,j+1))/dy**2.)
     >  -(dx**2./12.d0+dy**2./12.d0)
     >    *((s(i+1,j+1)+s(i-1,j+1)+s(i+1,j-1)+s(i-1,j-1))
     >       -2.d0*(s(i,j+1)+s(i+1,j)+s(i,j-1)+s(i-1,j))
     >       +4.d0*s(i,j))/(dx**2.*dy**2.)

      B=-Re*(dx**2./6.d0)
     >*(s(i+1,j+1)-s(i-1,j+1)-s(i+1,j-1)+s(i-1,j-1))/(4.d0*dx*dy)
     >+Re**2.*(dx**2./12.d0)*(s(i,j+1)-s(i,j-1))/(2.d0*dy)
     >                      *(s(i,j+1)-s(i,j-1))/(2.d0*dy)

      C=Re*(dy**2./6.d0)
     >*(s(i+1,j+1)-s(i-1,j+1)-s(i+1,j-1)+s(i-1,j-1))/(4.d0*dx*dy)
     >+Re**2.*(dy**2./12.d0)*(s(i+1,j)-s(i-1,j))/(2.d0*dx)
     >                      *(s(i+1,j)-s(i-1,j))/(2.d0*dx)

      D=(dx**2./12.d0+dy**2./12.d0)
     >*(s(i+1,j+1)+s(i-1,j+1)-s(i+1,j-1)-s(i-1,j-1)
     >+2.d0*(s(i,j-1)-s(i,j+1)))/(2.d0*dx**2.*dy)
     >-Re*(dx**2./12.d0)*(s(i,j+1)-s(i,j-1))/(2.d0*dy)
     >*(s(i+1,j+1)-s(i-1,j+1)-s(i+1,j-1)+s(i-1,j-1))/(4.d0*dx*dy)
     >+Re*(dy**2./12.d0)*(s(i+1,j)-s(i-1,j))/(2.d0*dx)
     >*(s(i,j+1)-2.d0*s(i,j)+s(i,j-1))/dy**2.

      E=(dx**2./12.d0+dy**2./12.d0)
     >*(s(i+1,j+1)-s(i-1,j+1)+s(i+1,j-1)-s(i-1,j-1)
     >+2.d0*(s(i-1,j)-s(i+1,j)))/(2.d0*dx*dy**2.)
     >-Re*(dx**2./12.d0)*(s(i,j+1)-s(i,j-1))/(2.d0*dy)
     >*(s(i+1,j)-2.d0*s(i,j)+s(i-1,j))/dx**2.
     >+Re*(dy**2./12.d0)*(s(i+1,j)-s(i-1,j))/(2.d0*dx)
     >*(s(i+1,j+1)-s(i-1,j+1)-s(i+1,j-1)+s(i-1,j-1))/(4.d0*dx*dy)

      F=(dx**2./12.d0+dy**2./12.d0)*(s(i,j+1)-s(i,j-1))/(2.d0*dy)
     >*(v(i+1,j+1)-v(i-1,j+1)+v(i+1,j-1)-v(i-1,j-1)
     >+2.d0*(v(i-1,j)-v(i+1,j)))/(2.d0*dx*dy**2.)
     >-(dx**2./12.d0+dy**2./12.d0)*(s(i+1,j)-s(i-1,j))/(2.d0*dx)
     >*(v(i+1,j+1)+v(i-1,j+1)-v(i+1,j-1)-v(i-1,j-1)
     >+2.d0*(v(i,j-1)-v(i,j+1)))/(2.d0*dx**2.*dy)
     >-(dx**2./6.d0)*(s(i+1,j)-2.d0*s(i,j)+s(i-1,j))/dx**2.
     >*(v(i+1,j+1)-v(i-1,j+1)-v(i+1,j-1)+v(i-1,j-1))/(4.d0*dx*dy)
     >+(dy**2./6.d0)*(s(i,j+1)-2.d0*s(i,j)+s(i,j-1))/dy**2.
     >*(v(i+1,j+1)-v(i-1,j+1)-v(i+1,j-1)+v(i-1,j-1))/(4.d0*dx*dy)
     >+Re*(dx**2./12.d0+dy**2./12.d0)
     >*(s(i+1,j)-s(i-1,j))/(2.d0*dx)*(s(i,j+1)-s(i,j-1))/(2.d0*dy)
     >*(v(i+1,j+1)-v(i-1,j+1)-v(i+1,j-1)+v(i-1,j-1))/(4.d0*dx*dy)
     >-(dx**2./12.d0-dy**2./12.d0)
     >*(v(i+1,j)-v(i-1,j))/(2.d0*dx)*(v(i,j+1)-v(i,j-1))/(2.d0*dy)
     >  -(1.d0/Re)*(dx**2./12.d0+dy**2./12.d0)
     >    *((v(i+1,j+1)+v(i-1,j+1)+v(i+1,j-1)+v(i-1,j-1))
     >       -2.d0*(v(i,j+1)+v(i+1,j)+v(i,j-1)+v(i-1,j))
     >       +4.d0*v(i,j))/(dx**2.*dy**2.)

      error_s_2=abs(
     > (s(i-1,j)-2.d0*s(i,j)+s(i+1,j))/dx**2.
     >+(s(i,j-1)-2.d0*s(i,j)+s(i,j+1))/dy**2.
     >+v(i,j)
     >-A
     >              )

      error_v_2=abs(
     > ((1.d0+B)*(v(i-1,j)-2.d0*v(i,j)+v(i+1,j))/dx**2.
     > +(1.d0+C)*(v(i,j-1)-2.d0*v(i,j)+v(i,j+1))/dy**2.)/Re
     > +((s(i+1,j)-s(i-1,j))/(2.d0*dx)+E)
     >                     *(v(i,j+1)-v(i,j-1))/(2.d0*dy)
     > -((s(i,j+1)-s(i,j-1))/(2.d0*dy)+D)
     >                     *(v(i+1,j)-v(i-1,j))/(2.d0*dx)
     >-F
     >)

      error_s_1=max(error_s_1,error_s_2)
      error_v_1=max(error_v_1,error_v_2)
 4    continue

      write(*,*) error_s_1,error_v_1

      open(2,file='out.dat')
      do 5 i=0,idim
      do 5 j=0,jdim
      write(2,10) x(i),y(j),s(i,j),v(i,j)
 5    continue
      close(2)

 10   format(f8.4,x,f8.4,x,es25.18,x,es25.18)

      stop
      end